flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104

{
  description = "Home Manager configuration of stefan";

  inputs = {
    # Specify the source of Home Manager and Nixpkgs.
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixgl = {
      url = "github:nix-community/nixgl";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    neovim-nightly = {
      url = "github:nix-community/neovim-nightly-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-hardware = {
      url = "github:NixOS/nixos-hardware/master";
    };
    ida-pro-overlay = {
      url = "github:msanft/ida-pro-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{
      self,
      nixpkgs,
      home-manager,
      nixgl,
      neovim-nightly,
      nixos-hardware,
      ...
    }:
    let
      system = "x86_64-linux";
      overlays = [
        inputs.nixgl.overlays.default
        inputs.neovim-nightly.overlays.default
        inputs.ida-pro-overlay.overlays.default
      ];
      pkgs = import nixpkgs {
        config.allowUnfree = true;
        inherit system overlays;
      };
      inherit (pkgs) lib;
    in
    {
      nixosConfigurations = {
        form = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = {
            inherit inputs;
          };
          modules = [
            ./form/configuration.nix
            home-manager.nixosModules.home-manager
            {
              home-manager = {
                users.stefan = import ./form/home.nix;
                useGlobalPkgs = true;
                useUserPackages = true;
                extraSpecialArgs = {
                  inherit system inputs pkgs;
                };
              };
            }
          ];
        };
        fw = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = { inherit inputs; };
          modules = [
            nixos-hardware.nixosModules.framework-13-7040-amd
            ./fw/configuration.nix
            home-manager.nixosModules.home-manager
            {
              home-manager = {
                users.stefan = import ./fw/home.nix;
                useGlobalPkgs = true;
                useUserPackages = true;
                extraSpecialArgs = {
                  inherit system inputs pkgs;
                };
              };
            }
          ];
        };
      };
      homeConfigurations = {
        inherit inputs system pkgs;
        "void" = home-manager.lib.homeManagerConfiguration {
          inherit pkgs;
          modules = [ ./void/home.nix ];
          extraSpecialArgs = {
            inherit system inputs pkgs;
          };
        };
      };
    };
}